今日份二选一：关于DID平行趋势检验基准组的选择
在普通DID平行趋势检验时，我们需要生成年份虚拟变量与处理组虚拟变量的交互项，然后将这些交互项作为解释变量进行回归。这时特别要注意一点，我们需要丢掉一期，作为基准组。很多朋友一直都不理解为什么要这么做，今天就想跟大家专门解释一下。
为什么需要基准组？
关于这个问题，你可能看到最多的回答是，从实际软件操作层面来看，不剔除一期作为基准组，就会存在共线性问题，就无法往下做了。但是这一回答还没有触及到问题的“灵魂”上来，我们首先需要明白平行趋势检验是在干嘛。
说起来其实很简单，平行趋势检验是在检验处理组和控制组在政策前的时间趋势是否存在差异（DID允许处理组和控制组存在差异，但是二者的时间趋势需要一致），我们需要有一期作为“标杆”（基准组），然后将其他各期与这一“标杆”进行对比，从而判断处理组与控制组的差异是否随时间发生了显著变化，如果没有一个“标杆”，那可能就是“关公战秦琼”，无从比较了。
基期还是-1期？
关于基准组的选择，我个人比较推荐的是选择第1期（基期，最开始的一期）或者-1期（政策时点前1期），注意不要选政策当期，因为政策当期已经受到政策影响了，政策后的各期那就更不能选了。
❝「使用基期的论文举例」
[1]Nathan Nunn, Nancy Qian. The potato's contribution to population and urbanization: evidence from a historical experiment[J]. The Quarterly Journal of Economics, 2011, 126(2):593-650.
[2]卞泽阳,李志远,徐铭遥.开发区政策、供应链参与和企业融资约束[J].经济研究,2021,56(10):88-104.
[3]陈钊,申洋.限购政策的空间溢出与土地资源配置效率[J].经济研究,2021,56(06):93-109.
[4]陈登科.贸易壁垒下降与环境污染改善——来自中国企业污染数据的新证据[J].经济研究,2020,55(12):98-114.
[5]蒋灵多,陆毅,张国峰.自由贸易试验区建设与中国出口行为[J].中国工业经济,2021(08):75-93.
「使用-1期的论文举例」
[1]Jia Ruixue. The Legacies of Forced Freedom: China's Treaty Ports[J]. Review of Economics and Statistics, 2014, 96(4):596-608.
[2]刘金科,肖翊阳.中国环境保护税与绿色创新：杠杆效应还是挤出效应?[J].经济研究,2022,57(01):72-88.
[3]李硕,王敏,张丹丹.中央环保督察和企业进入:来自企业注册数据的证据[J].世界经济,2022,45(01):110-132.
[4]谌仁俊,肖庆兰,兰受卿,刘嘉琪.中央环保督察能否提升企业绩效?——以上市工业企业为例[J].经济评论,2019(05):36-49.
[5]罗知,赵奇伟,严兵.约束机制和激励机制对国有企业长期投资的影响[J].中国工业经济,2015(10):69-84.
❞
操作实例
本例中，时间窗口是2005-2015年，政策时点是2012年，政策时点前有7期，政策时点后有3期。
如果选择基期作为基准组，那就是以政策前第7期（2005年）为“标杆”，我们需要丢掉pre7，所以绘制出来的平行趋势图中就也不会有政策前第7期的估计系数和置信区间。关于DID平行趋势检验绘图的相关操作和代码解释可以参见我之前的推文“双重差分法（DID）平行趋势检验的Stata操作”和“电动车”还是“自行车”？| 关于DID平行趋势检验绘图的相关操作（2.0版本）”这两篇推文，在此就不赘述了。
** 选择基期作为基准组
preserve
drop pre7 //删除基期
reghdfe lnrso pre* current post* $xlist ,absorb(id year) vce(cluster id)
coefplot, baselevels ///
keep(pre* current post*) ///
vertical ///转置图形
coeflabels(pre6=-6 pre5=-5 pre4=-4 pre3=-3 pre2=-2 pre1=-1 ///
current=0 post1=1 post2=2 post3=3) ///
yline(0,lwidth(vthin) lpattern(solid) lcolor(teal)) ///
xline(7,lwidth(vthin) lpattern(solid) lcolor(teal)) ///
ylabel(-0.8(0.2)0.2,labsize(*0.85) angle(0)) xlabel(,labsize(*0.85)) ///
ytitle("Coefficients") ///
msymbol(O) msize(small) mcolor(gs1) ///plot样式
addplot(line @b @at,lcolor(gs1) lwidth(medthick)) ///增加点之间的连线
ciopts(recast(rline) lwidth(thin) lpattern(dash) lcolor(gs2)) ///置信区间样式
graphregion(color(white)) //白底
restore
如果选择-1期作为基准组，那就是以政策前第1期（2011年）为“标杆”，我们需要丢掉pre1，所以绘制出来的平行趋势图中就也不会有政策前第1期的估计系数和置信区间。
** 选择-1期作为基准组
preserve
drop pre1 //删除-1期
reghdfe lnrso pre* current post* $xlist ,absorb(id year) vce(cluster id)
coefplot, baselevels ///
keep(pre* current post*) ///
vertical ///转置图形
coeflabels(pre7=-7 pre6=-6 pre5=-5 pre4=-4 pre3=-3 pre2=-2 ///
current=0 post1=1 post2=2 post3=3) ///
yline(0,lwidth(vthin) lpattern(solid) lcolor(teal)) ///
xline(7,lwidth(vthin) lpattern(solid) lcolor(teal)) ///
ylabel(-0.8(0.2)0.2,labsize(*0.85) angle(0)) xlabel(,labsize(*0.85)) ///
ytitle("Coefficients") ///
msymbol(O) msize(small) mcolor(gs1) ///plot样式
addplot(line @b @at,lcolor(gs1) lwidth(medthick)) ///增加点之间的连线
ciopts(recast(rline) lwidth(thin) lpattern(dash) lcolor(gs2)) ///置信区间样式
graphregion(color(white)) //白底
restore
但是，这样可能就会显得有些突兀，突然从-2期就跳到第0期了，所以很多人都会在绘图时都会加上-1期的估计系数和置信区间（因为是基准组，所以系数和置信区间为0即可）。
总之，基期或者-1期都OK，究竟选择哪一期作为基准组，完全取决于作者的习惯和偏好，还有就是是否对你的论文有利（这个我想大家都明白！！！）。需要本文使用的数据和代码的朋友，请在公众号后台对话框内回复关键词“基准组”。